Własna kryptowaluta? To proste!

Niewątpliwie najpopularniejszym zastosowaniem inteligentnych kontraktów Ethereum są kampanie ICO (Initial Coin Offering). Jak to działa? Emitujemy cyfrowe tokeny, które w zależności od modelu biznesowego reprezentują udziały w firmie, licencje na produkty czy vouchery na usługi, których finalnie będziemy dostarczać.

Kapitał zgromadzony ze sprzedaży tokenów powinien przynajmniej teoretycznie zostać przeznaczony na rozwój projektu, budowę produktów oraz usług. Przedstawiony sposób finansowania budzi nadal wiele kontrowersji – podobnie zresztą jak inne zbiórki społecznościowe. W ramach ciekawostki odsyłam do pierwszej uczciwej kampanii ICO.

Oczywiście kryptowaluty stanowią również świetne narzędzie marketingowe. Możemy dystrybuować je zamiast punktów lojalnościowych zwiększając zaangażowanie naszych klientów.

W praktyce token w sieci Ethereum jest smart kontraktem napisanym zgodnie z określonym standardem w celu zapewnienia kompatybilności z tzw. portfelami kryptowalut (aplikacjami umożliwiającymi zarządzanie tokenami).

Cały proces implementacji własnej waluty został opisany krok po kroku na stronie www.ethereum.org/token.

Podstawowa implementacja tokenu (Minimum Viable Token) jest stosunkowo prosta.

pragma solidity ^0.4.20;

contract MyToken {

    // Tworzymy słownik: adres konta – liczba tokenów (balans)
    mapping (address => uint256) public balanceOf;

    // Podczas wdrożenia właściciel kontraktu otrzymuje wszystkie tokeny
    constructor(uint256 initialSupply) public {
        balanceOf[msg.sender] = initialSupply;
    }

    // Funkcja wykonuje transfer tokenów
    function transfer(address _to, uint256 _value) public {

        // Sprawdzamy czy nadawca ma wystarczający balans
        require(balanceOf[msg.sender] >= _value);

        // Zabezpieczamy się przed potencjalnymi przepełnieniami
        require(balanceOf[_to] + _value >= balanceOf[_to]);

        // Zmniejszamy balans konta nadawcy
        balanceOf[msg.sender] -= _value;

        // Zwiększamy balans konta docelowego
        balanceOf[_to] += _value;
    }
}

Na stronie Ethereum znajdziemy również bardziej kompletną implementację wraz z dokładnym opisem oraz wyjaśnieniem poszczególnych funkcji. W ogólności kontrakt tokenu może zawierać bardziej złożone mechanizmy takie jak niszczenie czy emisję dodatkowych tokenów, zamrażanie poszczególnych kont, automatyczne sprzedawanie i wykupywanie waluty.

Stworzenie naszego pierwszego tokenu rozpoczynamy od skopiowania gotowej implementacji standardu ERC20 wspieranego przez portfele Ethereum. Następnie wdrażamy kontrakt za pomocą narzędzia Remix opisanego tutaj.

pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) external; }

contract TokenERC20 {
    // Public variables of the token
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    // 18 decimals is the strongly suggested default, avoid changing it
    uint256 public totalSupply;

    // This creates an array with all balances
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // This generates a public event on the blockchain that will notify clients
    event Transfer(address indexed from, address indexed to, uint256 value);

    // This notifies clients about the amount burnt
    event Burn(address indexed from, uint256 value);

    /**
     * Constructor function
     *
     * Initializes contract with initial supply tokens to the creator of the contract
     */
    constructor(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // Update total supply with the decimal amount
        balanceOf[msg.sender] = totalSupply;                // Give the creator all initial tokens
        name = tokenName;                                   // Set the name for display purposes
        symbol = tokenSymbol;                               // Set the symbol for display purposes
    }

    /**
     * Internal transfer, only can be called by this contract
     */
    function _transfer(address _from, address _to, uint _value) internal {
        // Prevent transfer to 0x0 address. Use burn() instead
        require(_to != 0x0);
        // Check if the sender has enough
        require(balanceOf[_from] >= _value);
        // Check for overflows
        require(balanceOf[_to] + _value >= balanceOf[_to]);
        // Save this for an assertion in the future
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // Subtract from the sender
        balanceOf[_from] -= _value;
        // Add the same to the recipient
        balanceOf[_to] += _value;
        emit Transfer(_from, _to, _value);
        // Asserts are used to use static analysis to find bugs in your code. They should never fail
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * Transfer tokens
     *
     * Send `_value` tokens to `_to` from your account
     *
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * Transfer tokens from other address
     *
     * Send `_value` tokens to `_to` on behalf of `_from`
     *
     * @param _from The address of the sender
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * Set allowance for other address
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * Set allowance for other address and notify
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf, and then ping the contract about it
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     * @param _extraData some extra information to send to the approved contract
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * Destroy tokens
     *
     * Remove `_value` tokens from the system irreversibly
     *
     * @param _value the amount of money to burn
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // Check if the sender has enough
        balanceOf[msg.sender] -= _value;            // Subtract from the sender
        totalSupply -= _value;                      // Updates totalSupply
        emit Burn(msg.sender, _value);
        return true;
    }

    /**
     * Destroy tokens from other account
     *
     * Remove `_value` tokens from the system irreversibly on behalf of `_from`.
     *
     * @param _from the address of the sender
     * @param _value the amount of money to burn
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // Check if the targeted balance is enough
        require(_value <= allowance[_from][msg.sender]);    // Check allowance
        balanceOf[_from] -= _value;                         // Subtract from the targeted balance
        allowance[_from][msg.sender] -= _value;             // Subtract from the sender's allowance
        totalSupply -= _value;                              // Update totalSupply
        emit Burn(_from, _value);
        return true;
    }
}

Warto zwrócić uwagę na zmienną decimals, która określa precyzję (podzielność tokenu). W przypadku gdy token reprezentuje dobra niepodzielne np. licencje powinniśmy przypisać jej wartość 0 i tworzyć tzw. tokeny niepodzielne.

Wdrażając kontrakt podajemy początkową liczbę tokenów, pełną nazwę oraz symbol – w moim przypadku Blockchain School Coin (BSC).

Wszystkie tokeny zostają przypisane do konta, z którego wysłaliśmy transakcję tworzącą kontrakt. Wtyczka MetaMask wyświetla listę oraz ilość należących do nas tokenów w zakładce TOKENS.

Niestety domyślnie widoczne są tylko popularne (zarejestrowane) tokeny. Aby śledzić balans nowo utworzonego tokenu musimy wprowadzić jego dane – przycisk ADD TOKEN.

Finalnie naszym oczom powinna ukazać się liczba posiadanych tokenów ?

W jaki sposób dystrybuować naszą cyfrową walutę? Niestety wtyczka aktualnie nie wspiera tej funkcjonalności – możemy natomiast skorzystać z serwisu www.myetherwallet.com.

Na starcie wybieramy sieć, w której znajduje się wdrożony kontrakt – w moim przypadku jest to sieć testowa Rinkeby.

W kolejnym kroku przechodzimy do zakładki Send Ether & Tokens i łączymy się z wtyczką MetaMask.

Następnie w prawym dolnym rogu wprowadzamy dane tokenu – analogicznie do operacji, którą wykonaliśmy w rozszerzeniu MetaMask.

Na tym etapie jesteśmy gotowi do wygenerowania transakcji, która pośle określoną ilość utworzonej kryptowaluty na konto o podanym adresie.

Po wykonaniu transakcji zaobserwujemy zmianę liczby tokenów przypisanych do konta nadawcy – w tym przypadku właściciela większości tokenów (twórcy kontraktu).

Okazuje się, że stworzenie własnej kryptowaluty jest dość proste. Jednak to nie jedyne zastosowanie technologii Blockchain, która zatacza coraz szersze kręgi w świecie IT i poza rynkiem walutowym i transakcjami bankowymi sięga wszędzie tam, gdzie są potrzebne niezaprzeczalne potwierdzenia akcji. I tak na przykład wykorzystany może być do potwierdzonej komunikacji, czy organizacji wyborów rządowych.